Hi All,

I have been an avid reader of this forum for a while. I just thought I would contribute to an internet that I have taken so much from...

Here is a replica of Scalper Buys and Sells. As far as I can tell, it matches up perfectly. If you would like to use it along with the Heiken-Ashi paintbars, I recommend you set the plot thickness to at least two more than the thickness of the Heiken-Ashi (In the attached picture, the Scalper Indicator is set to 3 and the Heiken-Ashi is set to 1). Also, please note that candlesticks are not supported.

Bugs/feedback are appreciated. I hope you all enjoy. Happy Trading,

Luis

p.s. For those of you who like to use candlesticks, I also have a ShowMe version, which places a dot on the highs/lows...Let me know if there is interest.

[mdb770]

Could you please post the source code so I could port it to Amibroker?
Thanks!

[traderlu]

Originally Posted by mdb770 »

Could you please post the source code so I could port it to Amibroker?
Thanks!

sure thing, here goes:

{Scalper Buys and Sells		7/18/2007
	Written by Luis Gomez 
	inspired by John Carters "Mastering the Trade"
}

inputs:
	buyColor(white),
	sellColor(white),
	width(3);
variables:
	highBarsAgo(1),
	possibleHighBarsAgo(1),
	possibleHigh(-2),
	hightoBeat(-1),
	barsSincePaint(1),
	lowBarsAgo(1),
	possibleLowBarsAgo(1),
	possibleLow(10000001),
	lowtoBeat(10000000),
	triggerPriceSell(-1),
	triggerPriceBuy(1000000),
	trend(1),
	_UP(1),
	_DOWN(-1),
	_ON(1),
	_OFF(-1);


//***************************************************
//****** Find and plot the highest swing high *******
//***************************************************

if trend = _UP then begin
	if swingHighBar(1,H,2,barsSincePaint+2) > -1 then begin
		possibleHighBarsAgo = swingHighBar(1,H,2,barsSincePaint+2);
		possibleHigh = H[possibleHighBarsAgo];
	end;

	if possibleHigh >= hightoBeat then begin
		highBarsAgo = possibleHighBarsAgo;
		hightoBeat = possibleHigh;
		triggerPriceSell = L[HighBarsAgo - 1];
	end;
	
	if C < triggerPriceSell and 
		highest(high,highBarsAgo) < hightoBeat then begin
		plotpb[highBarsAgo](H[highBarsAgo],L[highBarsAgo],"",sellColor);
		alert("Scalper Sell");
		trend = _DOWN;
		barsSincePaint = highBarsAgo-1;
		hightoBeat = -1;
		lowtoBeat = 10000000;
		triggerPriceBuy = 10000000;
		triggerPriceSell = -1;
		highBarsAgo = 1;
		possibleHigh = -2;
	end;

end;

//***************************************************
//****** Find and plot the lowest swing low *********
//***************************************************

if trend = _DOWN then begin
	if swingLowBar(1,L,2,barsSincePaint+2) > -1 then begin
		possibleLowBarsAgo = swingLowBar(1,L,2,barsSincePaint+2);
		possibleLow = L[possibleLowBarsAgo];
	end;

	if possibleLow <= lowtoBeat then begin
		lowBarsAgo = possibleLowBarsAgo;
		lowtoBeat = possibleLow;
		triggerPriceBuy = H[LowBarsAgo - 1];
	end;
	
	if C > triggerPriceBuy and 
	lowest(L,lowBarsAgo) > lowtoBeat then begin
		plotpb[lowBarsAgo](H[lowBarsAgo],L[lowBarsAgo],"",buyColor);
		alert("Scalper Buy");
		trend = _UP;
		barsSincePaint = lowBarsAgo-1;
		possibleLow = 10000001;
		lowtoBeat = 10000000;
		hightoBeat = -1;
		triggerPriceBuy = 10000000;
		triggerPriceSell = -1;
		lowBarsAgo = 1;
	end;		

end;

barsSincePaint = barsSincePaint+1;
if trend = _UP then highBarsAgo = highBarsAgo + 1;
if trend = _DOWN then lowBarsAgo = lowBarsAgo + 1;
setPlotWidth(1,width);

All I ask is that my name stay in the code, please. Thanks, and enjoy!

[dovetree]

Hi Trader Lu, Thanks for the code it works in 2000i with some modification. However, the white paint bar completely blots out the colour of the underlying heiken ashi colour (unlike your attached thubnail). I have tried changing the thickness of both the HA and scalper b/s but still get just a white bar.... any suggestions ?

Thanks

[Blu-Ray]

Originally Posted by dovetree »

Hi Trader Lu, Thanks for the code it works in 2000i with some modification. However, the white paint bar completely blots out the colour of the underlying heiken ashi colour (unlike your attached thubnail). I have tried changing the thickness of both the HA and scalper b/s but still get just a white bar.... any suggestions ?

Thanks

Dovetree

Traderlu has also kindfully done it in a "show me" edition, shown here:

http://www.traderslaboratory.com/for...tion-2127.html

Try transferring your code into a "Show me" indicator.

Cheers

Blu-Ray

[traderlu]

Originally Posted by dovetree »

Hi Trader Lu, Thanks for the code it works in 2000i with some modification. However, the white paint bar completely blots out the colour of the underlying heiken ashi colour (unlike your attached thubnail). I have tried changing the thickness of both the HA and scalper b/s but still get just a white bar.... any suggestions ?

Thanks

Dovetree,

I have had that same problem. I think it has to do with the order in which you add the analysis techniques to your chart. Try adding the Heiken-Ashi first, then the Scalper, or vice-versa. I can't remember which was the right order. Just don't add them at the same time. This should do the trick. And don't forget the thickness! Hope this helps

-Luis

[Armand]

Hope I'm not out of line here...but I use Sierra charts and the code that they use is C++. Does anyone know how difficult is it to convert code like Traderlu posted to C++. Does anyone have experience doing this or are there any examples of how to convert TS code to C++? Thx

[jjthetrader]

Hi, the paintbar shown in the photos of this indicator with the blue and red bars, is there accompanying code for this?

[thrunner]

Originally Posted by jjthetrader »

Hi, the paintbar shown in the photos of this indicator with the blue and red bars, is there accompanying code for this?

Those are the well known Heikin Ashii bars, http://www.traderslaboratory.com/for...cator-951.html
aka TTM trend borrowed/popularized by John Carter.