Here is a 'very inexpensive' alternative to Juriks Moving Average contributed in Easy Language by John D. McCormick (TS handle = JDM, see jmactrader.com).

Moving Averages are used to remove noise. By “noise” is meant the apparently random motion up and down of the prices around their average price. This shows up on a moving average as a jagged appearance on an otherwise smooth line. The jaggedness can trigger false buy and sell signals or simply make the indicator hard to read, so we try to smooth out the average, i.e. remove the noise.

Lagging or lateness is the bane of moving averages. You make them longer (average in more bars) and the moving average is smoother, but now it lags way behind the actual price movement.

The ideal moving average should filter out noise and respond quickly – and – it would be a plus if it was fast calculating. That’s kind of like having your cake and eating it too.

Nevertheless, here’s one, I call it Quick MA, that seems to work as well as any I’ve seen.

Full thread is at https://www.tradestation.com/Discuss...txtExactMatch=
Posted with his permission. Please retain his 'copyright' info in the code. Many thanks to JDM.

[zdo]

And here is the source in readable text

Indicator

//
//	Plots a fractional-bar Quick Moving Average 
//	with the option to select gapless daily opens.
//
//	copyright 2008 John McCormick jmactrader.com
//
//	feel free to copy and use this code royalty free
//	as long as it retains the above acknowledge
//

inputs:
	Price(Close),
	Quick_Length(9),
	displace(0),
	gapless(0);	// set gap to a non-zero value to skip over opening daily gaps

Var: Length(maxlist(1,Quick_Length));

// GapLess
	
Vars:			// gapless O,H,L,C where O=C[1]
	RelO(0),
	RelH(0),
	RelL(0),
	RelC(0),
	gap(0),
	Accum(0),
	WtMean(0);

if date<>date[1] then begin
	gap		=	O-C[1];
	Accum	=	Accum+gap;
end;

RelO	=	O-Accum;
RelC	=	C-Accum;
RelH	=	H-Accum;
RelL	=	L-Accum;

				// Gapless bars - end

WtMean = (RelH+RelL+RelC)/3;

// End Gapless
		
if gapless=0 
	then plot1[displace](FMA_Smooth(price,length),"FMA_Quick")
	else plot1[displace](FMA_Smooth(RelC,length)+accum,"FMA_Quick");

Function

//  generates very smooth and responsive moving average
// 	copyright 2008 John McCormick  jmactrader.com
//	feel free to copy and use this code royalty free 
//  as long as you don't remove the above acknowledgement
//		

Inputs: 
	Price(numericseries), 
	Length(numericsimple);

Vars:
	j(0),
	workinglen(maxlist(1,absvalue(Length))),
	peak(workinglen/3),
	tot(0),
	divisor(0);

Array:
val[100](0);

if workinglen>100 then workinglen=100;  //  use larger array to handle lengths over 100


tot=0;
divisor=0;
for j=1 to floor(workinglen+1) begin
	if j<=peak then val[j]=j/peak
	else val[j]=(workinglen+1-j)/(workinglen+1-peak);
	tot=tot+price[j-1]*val[j];
	divisor=divisor+val[j];
end;
if divisor<>0 then FMA_smooth=tot/divisor;

[zdo]

Here is a comparison of JurikMA (cyan) and QuickMA (yellow)

The arrows show spots where JMA beat QMA to the turn
(Note, though, there may be instances off this chart where QMA leads JMA)
Enjoy

[metalhead]

Wow! Here's the best I could do in that same time period (6/4 YM 1 min).

I'm very impressed by how smooth both of those are.

There's three in this pic: the light blue was my attempt at smoothing the thin pink one. The other thin pink one was another smooth attempt but it wasn't good.

Those up there are very, very smooth.

[pathfinder62]

QUOTE-Here is a comparison of JurikMA (cyan) and QuickMA (yellow)...

Great work & thanks for sharing/educating us. Tom M.

[Minis Trader]

I have been looking for a MA smoothing indicator similar to Juriks, thanks for sharing.

[rurimoon]

zdo, your graph show the Quick MA as yellow, and "AMA" as cyan... not JMA. Can you post another graph that have the QuickMA, AMA and JMA on 1 graph?

Thanks

[zdo]

Originally Posted by rurimoon »

zdo, your graph show the Quick MA as yellow, and "AMA" as cyan... not JMA. Can you post another graph that have the QuickMA, AMA and JMA on 1 graph?

Thanks

rurimoon,

Yellow is QuickMA
Cyan is really Jurik
(through the 90's it was the only adaptive mov avg I considered, hence the indicator label of "AMA" … (and obviously) it uses JMA function)
TS has an AdaptiveMovingAverage built in (Kaufman’s) but I would be afraid to even allow it to open on my screen …seriously and …
If you have TS you can try it... if not let me know and I will take some serious pain medication and put up a comparison. Keep in mind though that the kaufman effectively just 'dynamically' varies the length parameter via a stochastic rather than actually doing the 'phasing and whatever' that more recent ama do...
hth