[nasdaq5048]

Antonio,

I am trying to write a EL to identify a tail on a 30 min chart on easylanguage. I cant seem to get started. Could you please help me a little bit on that?

I dont know how to use array. Do you need array?


Thank you!

[ant]

Hi nasdaq5048,

An array is required to store the TPO count at each price.

The definition of a tail is at least two consecutive price levels with a TPO count equal to 1, either at the high or low of the Market Profile time period. This creates a selling tail or a buying tail. Tail is being defined here because this is what I would use to code the indicator.

Therefore, once you have an array with the TPO count at each price, check the two high prices in the array. If both prices have a TPO count equal to 1, then a selling tail exists. Reverse to identify a buying tail.

Attached is EL code that will display a number which indicates whether a tail exists in the Market Profile. This code will display one of the following values below the Market Profile:

0 = No Tails Exist
1 = Buying Tail Exists
2 = Selling Tail Exists
3 = Both a Buying Tail and a Selling Tail Exists

Apply the Market Profile indicator to your chart so that you can see the profile. Then apply the indicator attached. All of the code is unprotected so that you can make changes. This should get you started. Hope this helps.

[nasdaq5048]

Thanks a lot a lot. That really helps.
One question. Whether there is a tail is the variable tailsfound right? How come when i try to plot it using plot1, it doesnt show a value?
I am trying to use this on a radarscreen and see how many tails there were. So, i am trying to return a value if a tail exist.
So, i tried plot1(tailsfound,"Tail"); in the bottom of the code, and nothing shows up.

[ant]

nasdaq,

The tailsfound value is printed so you can verify it by comparing it to the Market Profile. To plot tailsfound, place the Plot1(...) command under the Text_Style(...) command (shows up twice). Remember that tailsfound is computed at the end of the day. You'll see what I mean once you plot it.

[nasdaq5048]

Thanks, i got it now.
I ran into this problem which the tailsexist function count the last bar as tail too. So, if they close on the high of the day of the last bar, the function count it as selling tail. I tried to modify the function but no luck.

I add 2 variables hi, lo on the tailexist function
if time = 1615 then hi = high;
if time = 1600 then lo = low;
and change
if NumTPOs[Index] = 1 and NumTPOs[Index+1] = 1 and lowd(0) <> lo then
begin
TailsFound = 1;
end;
if NumTPOs[Index] = 1 and NumTPOs[Index-1] = 1 then
begin
if TailsFound = 1 and highd(0) <> hi then
TailsFound = 3
else
TailsFound = 2;
end;

It doesnt seems to work. It still sees the last bar as a tail. I am just trying to ignore the tail if the high is made on the last bar or the low is made on the last bar. But no luck at all.

[ant]

Here you go nasdaq... Use this code for the TailsExist function. It will disregard a tail if the high or low was made in the last bar of the day. I believe this is what you were trying to achieve, which makes sense. That was a good catch. Good Luck!

P.S. Nasdaq, you had the right idea in your code, just required a little tweaking.

inputs:
	LL( NumericSimple ),
	HH( NumericSimple ),
	Offset( NumericSimple ),
	PriceAtIndex( NumericSimple ),
	TickSize( NumericSimple ),
	NumTPOs[n]( NumericArrayRef );

variables:
	Index( 0 ),
	TailsFound( 0 ),
	rc( 0 );

TailsFound = 0;

// Get the array index for the lowest price of the Market Profile range
rc = GetArrayIndex( LL, Offset, PriceAtIndex, TickSize, Index );

// Check if there is a buying tail
if NumTPOs[Index] = 1 and NumTPOs[Index+1] = 1 then
begin
	if Date <> Date[1] then
	begin
		// Was the last bar of the day also the low of the day?
		// If not, then mark it as a selling tail
		if Low[1] <> LowD(1) then
			TailsFound = 1;
	end
	else if LastBarOnChart then
	begin
		// Was the last bar on chart also the low of the day? 
		// if not, then mark it as a selling tail
		if Low <> LowD(0) then
			TailsFound = 1;
	end;	
end;
	
// Get the array index for the highest price of the Market Profile range
rc = GetArrayIndex( HH, Offset, PriceAtIndex, TickSize, Index );

// Check if there is a buying tail
if NumTPOs[Index] = 1 and NumTPOs[Index-1] = 1 then
begin
	if Date <> Date[1] then
	begin
		// Was the last bar of the day also the high of the day?
		// If not, then mark it as a buying tail
		if High[1] <> HighD(1) then
		begin
			if TailsFound = 1 then
				TailsFound = 3
			else
				TailsFound = 2;
		end;
	end
	else if LastBarOnChart then
	begin
		// Was the last bar on chart also the high of the day? 
		// if not, then mark it as a buying tail
		if High <> HighD(0) then
		begin
			if TailsFound = 1 then
				TailsFound = 3
			else
				TailsFound = 2;
		end;
	end;
end;

TailExists = TailsFound;

[ant]

The chart below illustrates the use of the MP_Tails indicator.

[nasdaq5048]

Thank you Antonio, is very kind of you for the help. I am no computer literate as you can tell. I just learn EL all by myself through the forums.