Market Delta is 3rd party software that provides interesting ways of viewing bid/ask information. This information could be useful for analyzing market behavior as price approaches a key support/resistance level.

For those that use tradestation, I have created a simulation of Market Delta. Note that tradestation provides a snapshot of the bid/ask so it won't be accurate most of the time. Therefore, I have provided an option in this analysis technique to use upticks and downticks instead. Although the bid/ask info is not completely accurate in tradestation, you can determine whether it is good enough or if using upticks/downticks is preferred. This Market Delta indicator defaults to using upticks/downticks, which I find useful. For example, in the first chart below, a downswing is highlighted in the ES on 8/29. In the second chart, you can see that the simulation of Market Delta using upticks/downticks highlighted the net selling.

Additional Information about the Indicator
Attached is the code to simulate Market Delta. Note that if you apply this indicator to a chart and then refresh that chart, all of the Volume info at each strike price is lost. This code does not save historical information.

The code supports four color gradients that are controlled by the Threshold inputs. The default Threshold settings are appropriate for the ES on a 5 or 15 minute chart. Setting the Type parameter to '1' will use upticks/downticks, setting that parameter to '2' will use bid/ask. The DisplayDelta parameter indicates whether the net selling vs net buying delta is displayed below the bars (see example below). This code can be easily modified to display Volume at each strike. This is a Paintbar indicator.

From my observation, the footprint is updated in real-time in a timely manner. Experiment and play with it and see if you find it useful. Make sure to spread out the bars so that the data and bars fit neatly. I have tested this primarily with the emini S&P. This indicator was originally posted to the tradestation Forum where other traders are making enhancements to it.

[jmi88]

I have prosuite2000i, and it dosent import eld files....is there anyway you can post the code so i can paste it into the EL editor? it would be greatly appreciated...

[ant]

Originally Posted by jmi88 »

I have prosuite2000i, and it dosent import eld files....is there anyway you can post the code so i can paste it into the EL editor? it would be greatly appreciated...

As far as I know, this indicator cannot be supported by TS2000i or any tradestation version prior to 8.1 because of limitations related to making updates/calculations on every tick. Sorry.

[torero]

ant. Excellent work and contribution! I've been very interested in using this but didn't know TS had one until I found this forum. Thanks very much!

[Reaver]

Nice job, man!

[MarketMole]

I don't suppose it would be possible to paste the actual TS code into this thread?

Many thanks,
MarketMole
~bangeye~

[ant]

Originally Posted by MarketMole »

I don't suppose it would be possible to paste the actual TS code into this thread?

Many thanks,
MarketMole
~bangeye~

Here you go MarketMole...

inputs:
Threshold1( 150 ),
Threshold2( 300 ),
Threshold3( 600 ),
DisplayDelta( false ),
Type( 1 ), // 1 = Use Upticks/Downticks, 2 = Use Bid/Ask
BidAskArraySz( 1000 );

variables:
TickSize( MinMove / PriceScale ),
PriceAtIndex( Open ),
BaseIndex( BidAskArraySz/2 ),
Red1(RGB(255,185,185)),
Red2(RGB(255,128,128)),
Red3(RGB(255,0,0)),
Red4(RGB(128,0,0)),
Green1(RGB(210,255,210)),
Green2(RGB(125,255,125)),
Green3(RGB(0,255,0)),
Green4(RGB(0,128,0)),
i( 0 );

variables:
intrabarpersist Price( 0 ),
intrabarpersist MyVol( 0 ),
intrabarpersist VolTmp( 0 ),
intrabarpersist LastTick( 0 ),
intrabarpersist MyCurrentBar( 0 ),
intrabarpersist Index( 0 ),
intrabarpersist BidAskDelta( 0 ),
intrabarpersist xDelta( 0 ),
intrabarpersist TextString(""),
intrabarpersist MyUpTicks( 0 ),
intrabarpersist MyDownTicks( 0 );

Arrays:
intrabarpersist Bid[](0),
intrabarpersist Ask[](0);

Array_SetMaxIndex( Bid, BidAskArraySz );
Array_SetMaxIndex( Ask, BidAskArraySz );

if (Type = 1 or Type = 2) and LastBarOnChart and BarType < 2 then
begin
MyVol = Ticks;
PriceAtIndex = Open;

if CurrentBar > MyCurrentBar then
begin
VolTmp = 0;
MyCurrentBar = CurrentBar;
MyUpTicks = 0;
MyDownTicks = 0;

for i = 0 to BidAskArraySz - 1
begin
Bid[i] = 0;
Ask[i] = 0;
end;
end;

Index = BaseIndex + (Close - PriceAtIndex) / TickSize;

if InsideBid < InsideAsk then
begin
if Type = 1 then
begin
// Use Upticks/Downticks
if DownTicks <> MyDownTicks then
Bid[Index] = Bid[Index] + MyVol - VolTmp
else if UpTicks <> MyUpTicks then
Ask[Index] = Ask[Index] + MyVol - VolTmp
else
begin
if Close <= LastTick then
Bid[Index] = Bid[Index] + MyVol - VolTmp
else
Ask[Index] = Ask[Index] + MyVol - VolTmp;
end;
end
else
begin
// Use Bid/Ask
// Warning: tradestation provides snapshot of bid/ask
if Close <= InsideBid then
Bid[Index] = Bid[Index] + MyVol - VolTmp
else if Close >= InsideAsk then
Ask[Index] = Ask[Index] + MyVol - VolTmp
else
begin
// Last tick was between bid/ask
if Close <= LastTick then
Bid[Index] = Bid[Index] + MyVol - VolTmp
else
Ask[Index] = Ask[Index] + MyVol - VolTmp;
end;
end;
end;

MyUpTicks = UpTicks;
MyDownTicks = DownTicks;
VolTmp = MyVol;
LastTick = Close;

xDelta = 0;
Price = Low;

while Price <= High
begin
Index = BaseIndex + (Price - PriceAtIndex) / TickSize;
TextString = NumToStr(Bid[Index],0) + " x " + NumToStr(Ask[Index],0);
Value99 = Text_New(Date, Time, 0, " ");
Text_SetString(Value99, TextString);
Text_SetLocation(Value99, Date, Time, Price);
Text_SetStyle(Value99, 1, 1);

BidAskDelta = Ask[Index] - Bid[Index];
if BidAskDelta > Threshold3 then
Text_SetColor(Value99, Green4)
else if BidAskDelta > Threshold2 then
Text_SetColor(Value99, Green3)
else if BidAskDelta > Threshold1 then
Text_SetColor(Value99, Green2)
else if BidAskDelta >= 0 then
Text_SetColor(Value99, Green1)
else if BidAskDelta < -Threshold3 then
Text_SetColor(Value99, Red4)
else if BidAskDelta < -Threshold2 then
Text_SetColor(Value99, Red3)
else if BidAskDelta < -Threshold1 then
Text_SetColor(Value99, Red2)
else
Text_SetColor(Value99, Red1);

xDelta = xDelta + BidAskDelta;

Price = Price + TickSize;
end;

if DisplayDelta = true then
begin
Value99 = Text_New(Date, Time, 0, " ");
Text_SetString(Value99, NumToStr(xDelta, 0 ));
Text_SetLocation(Value99, Date, Time, Low - TickSize);
Text_SetStyle(Value99, 1, 1);

if xDelta >= 0 then
Text_SetColor(Value99, Green)
else
Text_SetColor(Value99, Red);
end;
end;

[MarketMole]

ant,

Thank you - your gesture is most appreciated. I had to copy from the ViewSource of the browser to get the line brakes but that worked just fine.

Have a big day.
MM