[ajhunter]

I would like to generate an indicator telling me when at what closing price would be required to change the direction of a Hull moving average. I am currently do not understand the Hull moving average function and am therefore unable to do the math/coding.

Value1 = 2 * WAverage(price, halvedLength);
Value2 = WAverage(price, length);
Value3 = WAverage((Value1 - Value2), sqrRootLength);

jtHMA = Value3;

I understand and can calculate value1 and value2 but I have no idea what a weighted average of the difference between the two actually is. I read value3 as being a weighted average of an integer over the squareroot of a period. But a weighted average of an integer makes no sense .

Some elucidation would be greatly appreciated.

[zapisy]

Indicator:

Inputs: Length(20), Offset(0); 
 
 
vars: avg1(0), color1(black); 
 
 
avg1 = jthma(Close, Length); 
 
Plot1 (avg1, "JT Hull"); 
 
color1 = green; 
if avg1 < avg1[1] then color1 = red; 
 
SetPlotColor[Offset](1, color1);

Function

{jtHMA - Hull Moving Average Function}  
{Author: Atavachron}  
{May 2005}		  
	  
Inputs: price(NumericSeries), length(NumericSimple);  
Vars: halvedLength(0), sqLength(0), sqrRootLength(0);  
  
{  
 Original equation is:  
 ---------------------  
 waverage(2*waverage(close,period/2)-waverage(close ,period), SquareRoot(Period)  
 Implementation below is more efficient with lengthy Weighted Moving Averages.  
 In addition, the length needs to be converted to an integer value after it is halved and  
 its square root is obtained in order for this to work with Weighted Moving Averaging  
}  
  
if ((ceiling(length / 2) - (length / 2))  <= 0.5) then  
	halvedLength = ceiling(length / 2)  
else  
	halvedLength = floor(length / 2);  
 
sqLength = SquareRoot(length); 
  
if ((ceiling(sqLength) - sqLength)  <= 0.5) then  
	sqrRootLength = ceiling(sqLength)  
else  
	sqrRootLength = floor(sqLength);  
  
Value1 = 2 * WAverage(price, halvedLength);  
Value2 = WAverage(price, length);  
Value3 = WAverage((Value1 - Value2), sqrRootLength);  
  
jtHMA = Value3;

[Tams]

Originally Posted by ajhunter »

I would like to generate an indicator telling me when at what closing price would be required to change the direction of a Hull moving average. I am currently do not understand the Hull moving average function and am therefore unable to do the math/coding.

Value1 = 2 * WAverage(price, halvedLength);
Value2 = WAverage(price, length);
Value3 = WAverage((Value1 - Value2), sqrRootLength);

jtHMA = Value3;

I understand and can calculate value1 and value2 but I have no idea what a weighted average of the difference between the two actually is. I read value3 as being a weighted average of an integer over the squareroot of a period.

1. value3 is not necessary an integer.

Originally Posted by ajhunter »

But a weighted average of an integer makes no sense .

Some elucidation would be greatly appreciated.

2. what/why does it makes no sense?

[ajhunter]

The weighted average formula divides wtd sum by cumulative weight, where the weighted sum is generated by adding up different prices over the course of the relevant time period and multiplying them by the length (day in the period) associated with them.

JTHMA appears to be essentially a weighted average of other weighted averages -- specifically two weighted averages that have two different periods (length and halvedlength).

Here's where I'm confused. Weighted average for (price, length) requires a different price for each period included in the length -- So if I have a length of 5, I need a price for each of those five values of length. However the JTHMA formula just gives me one price (the real number, representing Value1-Value2), despite the fact that it has a length greater than 1.

Many thanks for any light you can shed on this!

[flyingdutchmen]

a possible solution to being able to tell what price it will need in order to change direction
is to stick it in a loop and let it find out itself.
i am not sure what you are trying to achieve, if for example your indikator, which in this case is the hull ma is pointing up and you would want to know how much price should move down in order to make your indikator go down or cross below some fix point whithout knowing or needing to know the exact calculations it shouldnt be to hard to find out.
stick the calculation in a loop and let it loop trough untill your disired outcome is calculated, this will then be the price you will need to achieve the theoretical change in the indikator you would like to see.
but then again, imho it is not very helpfull to use an indikator from which one does not know on which formula's it is based.
if you need help let me know this should not be very hard to realize, im not sure if it is what you are trying to achieve here

[statsign]

Weighted average of the difference of price averages with a length of the square root of length(input)

Value1 = 2 * WAverage(price, halvedLength); double weights (the 2 * part) the weighted average of price with a period of 1/2 (fast length) the period that you choose with the input length (Inputs: Length(20), Offset(0); ) more on that below

Value2 = WAverage(price, length); is the weighted average of price with a period you chose with the input length (slow length). (obviously, I know)

Your choice of period you make with the input length is supposed to be made with some kind of statistically significant decision process. You should have a reason why you choose this number. This length is the longest length (slow length) used in the Hull Moving Average so a good setting is the longest moving average period that you generally like using for a moving average you use on your chart (especially if it is a weighted moving average you use) but double the number if your moving average you like moves right up and down with the general price cycles (especially if it is a weighted moving average you consider to show most of the movement cycles).

Value3 = WAverage((Value1 - Value2), sqrRootLength); is the weighted average of the difference of the double weighted fast price average and the slow weighted average of price and so it is a rate of change indicator. Many indicators use some kind of fast and slow comparison like this. Using a period of 1/2 of the slow length for the fast length in the equation is based on the slow length being statistically valid for smoothing cycles, thus 1/2 length should move with the cycles. The period used sqrRootLength in this case for the weighted average of the difference is a very fast length so that your hull moving average is of very reduced lag. Some would say that since this period is the square root of the slow length (if really statistically valid) then it is statistically valid- but I haven't tested this.
Ceiling - Returns the lowest integer greater than the specified number.
Floor - Returns the highest integer less than the specified number.

The Hull average is most generally used to produce smooth indicators for short time frame charts. I have a simple example for showing 2 fast stochastics, 2 because I am way
too dumb to input a statistically significant length so I hope I choose one that then being halved again will keep somewhere in between and show a significant cycle - which seems to help.

Inputs: length(20), EOB(true); 


vars: FastStochastic(0), FastStochastic2(0),	price1(0), price2(0), price3(0),
	halvedLength(0), sqrRootLength(0), sqLength(0),
	Havg(0), Lavg(0), Cavg(0),
	price4(0), price5(0), price6(0),
	halvedLength2(0), sqrRootLength2(0), sqLength2(0),
	halfHavg(0), halfLavg(0), halfCavg(0);

	if length < 4 then RaiseRunTimeError("Input length(period) must be 8 or greater"); //////// not required 
	/////////////- personal reminder

	price1 = (4 * H[3] + 3 * H[2]+ 2 * H[1] + H) * 0.1;
	price2 = (4 * L[3] + 3 * L[2]+ 2 * L[1] + L) * 0.1;
	price3 = (4 * C[3] + 3 * C[2]+ 2 * C[1] + C)  * 0.1;


	halvedLength = round(length * 0.5,0);  
	sqLength = SquareRoot(length); 
  
	if ((ceiling(sqLength) - sqLength)  <= 0.5) then  
		sqrRootLength = ceiling(sqLength)  
	else  
		sqrRootLength = floor(sqLength); 

	halvedLength2 = round(halvedLength * 0.5,0);  
	sqLength2 = SquareRoot(halvedLength); 

	if ((ceiling(sqLength2) - sqLength2)  <= 0.5) then  
		sqrRootLength2 = ceiling(sqLength2)  
	else  
		sqrRootLength2 = floor(sqLength2); 

	Value1 = 2 * WAverage(price1, halvedLength);
	Value2 = WAverage(price1, length);
	Havg = WAverage((Value1 - Value2), sqrRootLength);



	Value3 = 2 * WAverage(price2, halvedLength);
	Value4 = WAverage(price2, length);
	Lavg = WAverage((Value3 - Value4), sqrRootLength);


	Value5 = 2 * WAverage(price3, halvedLength);
	Value6 = WAverage(price3, length);
	Cavg = WAverage((Value5 - Value6), sqrRootLength);


	Value7 = 2 * WAverage(price1, halvedLength2);
	Value8 = WAverage(price1, halvedLength);
	halfHavg = WAverage((Value7 - Value8), sqrRootLength2);



	Value9 = 2 * WAverage(price2, halvedLength2);
	Value10 = WAverage(price2, halvedLength);
	halfLavg = WAverage((Value9 - Value10), sqrRootLength2);


	Value11 = 2 * WAverage(price3, halvedLength2);
	Value12 = WAverage(price3, halvedLength);
	halfCavg = WAverage((Value11 - Value12), sqrRootLength2);


	FastStochastic = FastKCustom(Havg, Lavg, Cavg, halvedLength);
	FastStochastic2 = FastKCustom(halfHavg, halfLavg, halfCavg, halvedLength2);


		plot1(FastStochastic,"Slow");
		plot2(FastStochastic2,"Fast");
		plot3(20);
		plot4(80);

		if EOB and CheckAlert Then Begin   //// set EOB to false for intrabar alerts
			If plot1 Crosses Over Plot4 Then
			Alert("FastStochastic _Slow_ crossed over 80"); 
			If plot1 Crosses Under Plot3 Then
			Alert("FastStochastic _Slow_  crossed under 20"); 
			If plot1 Crosses Over Plot3 Then
			Alert("FastStochastic _Slow_  crossed over 20"); 
			If plot1 Crosses Under Plot4 Then
			Alert("FastStochastic _Slow_  crossed under 80"); 
			If plot2 Crosses Over Plot4 Then
			Alert("FastStochastic _Fast_ crossed over 80"); 
			If plot2 Crosses Under Plot3 Then
			Alert("FastStochastic _Fast_  crossed under 20"); 
			If plot2 Crosses Over Plot3 Then
			Alert("FastStochastic _Fast_  crossed over 20"); 
			If plot2 Crosses Under Plot4 Then
			Alert("FastStochastic _Fast_  crossed under 80"); 
		End ;

and attached image:

[ajhunter]

Thanks Statsign, seeing the code expanded as you have done is very helpful. I appreciate the work.

ajhunter