[Tams]

Originally Posted by emptyvault »

oh , I just found that at MC home page .
There is vidya by Chande, let me see if it is the same old one .
thanks all .

don't just say "I found it".
For the benefit of all, and as a courtesy,
post a link of your find.

[flyingdutchmen]

this is from tradesignal enterprise should work with ts as well;
is this the vidya you were looking for

function "VIDYA"

Inputs: 
	Price( NumericSeries ), 
	Period( NumericSimple ),
	Smoothing( NumericSimple );

Variables: 
	absCMO, SC;

absCMO = Abs( CMO( Price, Period ) ) / 100;

SC = 2 / ( Smoothing + 1 );

If Currentbar > 1 And IsValid( VIDYA[1] ) Then 
	VIDYA = ( SC * absCMO * Price ) + ( 1 - ( SC * absCMO ) ) * VIDYA[1]
Else
	VIDYA = Price;

function "CMO" for VIDYA's calculation

Inputs:
	Price( NumericSeries ),
	Period( NumericSimple );

Variables:
	priceToday, pricePrev, sumUp, sumDown, i;

sumUp = 0; 
sumDown = 0;
For i = 0 To Period - 1 Begin
	priceToday = Price[i];
	pricePrev = Price[i+1];	
	If priceToday > pricePrev Then
		sumUp = sumUp + ( priceToday - pricePrev )
	Else If priceToday < pricePrev Then
		sumDown = sumDown + ( pricePrev - priceToday );
End;

If sumUp = 0 Then
	CMO = -100
Else If sumDown = 0 Then
	CMO = 100
Else If sumUp <> sumDown Then
	CMO = 100 * ( ( sumUp - sumDown ) / ( sumUp + sumDown ) )
Else
	CMO = 0;

VIDYA indicator

inputs: Price    ( Close ),
        Period   ( 14 ),
        Smoothing( 4 );

variables: myVIDYA(0);

myVIDYA = VIDYA( Price, Period, Smoothing );

plot1( myVIDYA,"VIDYA" );

[emptyvault]

The indicator was on MC homepage so I guess not all of the readers like me to just copy and paste the material on here .
sorry if you feel it is improper to do so .